Cách Sử Dụng Hàm VLOOKUP Trong Excel Chi Tiết, Dễ Hiểu Cho Người Mới

Nội dung bài viết được cố vấn chuyên môn bởi TS. Nguyễn Thị Chinh Lam - Giảng viên khóa học kế toán tổng hợp thực hành tại Kế Toán Lê Ánh.

Hàm VLOOKUP trong Excel là một trong những hàm tra cứu dữ liệu được sử dụng phổ biến nhất, đặc biệt với người làm kế toán, hành chính, nhân sự, bán hàng và các công việc thường xuyên xử lý bảng tính. Thay vì dò tìm thủ công từng dòng, VLOOKUP cho phép người dùng tìm một giá trị trong bảng dữ liệu và trả về thông tin tương ứng ở một cột khác.

Với công việc kế toán, hàm VLOOKUP thường được dùng để tra cứu tên hàng theo mã hàng, lấy đơn giá từ bảng danh mục, tìm thông tin khách hàng theo mã khách hàng, tra cứu tên nhân viên theo mã số hoặc đối chiếu dữ liệu giữa các bảng. Khi sử dụng đúng, hàm này giúp rút ngắn thời gian xử lý số liệu, hạn chế nhập liệu thủ công và giảm sai sót khi lập bảng tính, bảng lương, báo cáo bán hàng hoặc báo cáo kế toán.

Tuy nhiên, VLOOKUP cũng là hàm dễ trả về kết quả sai nếu người dùng chưa hiểu rõ cú pháp, chọn sai vùng tra cứu, không cố định bảng dữ liệu, dùng sai kiểu dò tìm hoặc để dữ liệu khác định dạng. Với dữ liệu kế toán, một lỗi nhỏ trong công thức có thể làm sai đơn giá, sai mã hàng, sai thông tin khách hàng hoặc ảnh hưởng đến số liệu tổng hợp.

Bài viết này, Kế toán Lê Ánh sẽ hướng dẫn cách sử dụng hàm VLOOKUP trong Excel theo hướng dễ hiểu, có ví dụ thực tế và phù hợp với người mới bắt đầu. Nội dung tập trung vào cách đọc cú pháp, cách viết công thức, cách áp dụng VLOOKUP trong công việc kế toán – văn phòng, các lỗi thường gặp và những lưu ý quan trọng trước khi dùng hàm cho báo cáo.

»» Xem thêm: Cách copy dữ liệu từ Excel sang Word giữ nguyên định dạng

1. Hàm Vlookup là gì?

Hàm VLOOKUP trong Excel (Vertical Lookup) là hàm dùng để tìm kiếm một giá trị trong cột đầu tiên của bảng dữ liệu và trả về thông tin tương ứng ở một cột khác. Nói cách khác, hàm này giúp bạn "tra cứu theo chiều dọc" trong bảng dữ liệu.

Ví dụ dễ hiểu:

• Bạn có một danh sách hàng hóa gồm mã hàng, tên hàng và đơn giá.
• Khi nhập mã hàng vào ô tra cứu, hàm VLOOKUP sẽ tự động trả về tên hàng hoặc đơn giá tương ứng, thay vì phải dò thủ công trong bảng.

Đây là lý do vì sao trong kế toán, hàm VLOOKUP trong Excel thường được sử dụng để:

• Tra cứu tên nhân viên theo mã nhân viên khi làm bảng lương.
• Tìm đơn giá theo mã hàng hóa trong phiếu nhập kho – phiếu xuất kho.
• Lấy tên khách hàng theo mã số thuế trong danh sách khách hàng.

2. Cú pháp hàm VLOOKUP trong Excel

Công thức chuẩn của hàm VLOOKUP là:

=VLOOKUP (lookup_value; table_array; col_index_num; [range_lookup])

Ý nghĩa các tham số

• lookup_value: Giá trị cần tìm trong cột đầu tiên của bảng dữ liệu. Ví dụ: mã hàng, mã nhân viên, mã số thuế.
• table_array: Vùng dữ liệu chứa cả cột để tìm kiếm và cột trả về.o Lưu ý: Cột đầu tiên của vùng này phải chứa lookup_value.
• col_index_num: Thứ tự cột trong vùng dữ liệu chứa giá trị cần trả về.o Ví dụ: 2 = cột thứ hai, 3 = cột thứ ba,…
• [range_lookup]: Tùy chọn, có 2 giá trị:
  • TRUE (1): Tìm kiếm gần đúng (nếu không tìm thấy chính xác, Excel sẽ trả về giá trị gần nhất).
  • FALSE (0): Tìm kiếm chính xác (nếu không có giá trị khớp hoàn toàn, trả về lỗi #N/A).
  • Trong kế toán và quản lý dữ liệu, hầu hết trường hợp nên dùng FALSE để tránh nhầm lẫn.

Ví dụ minh họa (kế toán)

Bạn có bảng dữ liệu hàng hóa:

Công thức: = VLOOKUP("A02"; A2:C4; 2; 0)

• Kết quả: Vở ô ly 200 trang
• Công thức:= VLOOKUP("A03"; A2:C4; 3; 0)
• Kết quả: 220.000

Với mẫu hàm VLOOKUP trong Excel như trên, bạn chỉ cần thay lookup_value là mã hàng, Excel sẽ tự động trả về thông tin cần tra cứu.

Khóa Học Kế Toán Online - Tương Tác Trực Tiếp Với Giảng Viên Kế Toán Trưởng Trên 15 Năm Kinh Nghiệm

3. Cách dùng hàm VLOOKUP trong Excel (4 bước)

Để dùng VLOOKUP đúng, người học nên đi theo 4 bước sau:

Bước 1: Xác định giá trị cần tra cứu

Trước tiên, cần xác định giá trị dùng để tra cứu là gì. Đây thường là mã hàng, mã nhân viên, mã khách hàng, mã nhà cung cấp hoặc mã tài khoản.

Ví dụ, khi cần lấy tên hàng theo mã hàng, giá trị cần tra cứu là mã hàng. Khi cần lấy thông tin nhân viên theo mã nhân viên, giá trị cần tra cứu là mã nhân viên.

Bước 2: Chọn bảng dữ liệu tra cứu

Bảng dữ liệu tra cứu phải chứa cả cột chứa giá trị cần tìm và cột chứa kết quả cần trả về. Với VLOOKUP, cột chứa giá trị cần tìm phải nằm ở cột đầu tiên của vùng được chọn.

Ví dụ, nếu cần tra cứu đơn giá theo mã hàng, bảng tra cứu nên có cột mã hàng ở ngoài cùng bên trái, sau đó là tên hàng, đơn vị tính, đơn giá hoặc các thông tin cần lấy.

Bước 3: Xác định số thứ tự cột cần trả về

Sau khi chọn bảng tra cứu, cần xác định kết quả muốn lấy nằm ở cột thứ mấy trong vùng dữ liệu.

Ví dụ, vùng tra cứu gồm:

• Cột 1: Mã hàng
• Cột 2: Tên hàng
• Cột 3: Đơn vị tính
• Cột 4: Đơn giá

Nếu muốn lấy tên hàng, col_index_num là 2. Nếu muốn lấy đơn giá, col_index_num là 4.

Bước 4: Chọn kiểu dò tìm chính xác hoặc gần đúng

Cuối cùng, cần chọn kiểu dò tìm. Với kế toán, nên ưu tiên 0 hoặc FALSE để tìm chính xác.

Ví dụ: =VLOOKUP(E2;$A$2:$D$100;4;0)

Công thức này tìm mã hàng tại ô E2 trong cột đầu tiên của vùng $A$2:$D$100, sau đó trả về dữ liệu ở cột thứ 4 và chỉ chấp nhận kết quả khớp chính xác.

Sau khi nhập công thức, kế toán nên kiểm tra lại:

• Mã cần tìm có tồn tại trong bảng tra cứu không.
• Cột đầu tiên của vùng tra cứu có đúng là cột chứa mã cần tìm không.
• Số thứ tự cột trả về đã đúng chưa.
• Vùng tra cứu đã được cố định bằng dấu $ chưa.
• Kiểu dò tìm đã dùng 0/FALSE trong trường hợp cần khớp chính xác chưa.

4. Ví dụ hàm VLOOKUP

4.1. Ví dụ về hàm Vlookup trong Excel

Ví dụ 1: Ta có 2 bảng excel như sau:

Yêu cầu: Thêm thông tin về Quê quán vào bảng bên trên

Cách thực hiện:

Bước 1: Click chuột vào ô E6

Bước 2: Đặt công thức: =VLOOKUP(A6,$D$12:$F$17,2,0)

Trong đó:

• A6 là giá trị cần tìm kiếm (ở đây mã nhân viên là dữ liệu chung giữa 2 bảng nên ta tìm mã nhân viên)
• $D$12:$F$17 là vùng dò tìm giá trị tìm kiếm (cần tìm mã nhân viên ở bảng 2 để lấy thông tin quê quán nên vùng dò tìm là toàn bộ bảng 2)
• 2 là số cột chứa thông tin cần tìm (đang muốn tìm thông tin quê quán. Quê quán là cột thứ 2 trong bảng 2)
• 0 là kiểu dò tìm chính xác

Bước 3: Sao chếp công thức xuống các dòng khác

Ta thu được kết quả: 

Ví dụ 2: 

Ví dụ cách sử dụng hàm vlookup

Nhìn vào 2 bảng ta có thể phân tích như sau: Cả 2 bảng đều có điểm chung là cột Xếp loại. Vì vậy để có được cột TIỀN CÔNG (Cột F) thì ta cần dựa vào xếp loại để tham chiếu với số tiền công tương ứng với xếp loại ở cột bên cạnh.

Trong trường hợp này ta sẽ sử dụng HÀM VLOOKUP, cách thực hiện như sau:

Tại ô F5 ta đặt công thức: =VLOOKUP(E5;$K$7:$N$11;3;0)

Trong đó: 

• E5: Là xếp hàng của nhân viên
• $K$7:$N$11 là bảng tham chiếu (khi chọn bảng nhấn F4 để cố định lại bảng)
• 3 là số thứ tự cột cần lấy dữ liệu
• 0 là kiểu dò tìm chính xác

 Sau đó kéo hàm cho cả cột ta sẽ được kết quả như sau:

Ví dụ cách sử dụng hàm vlookup trong Excel

Ví dụ 3: Cùng thực hành tiếp về cách sử dụng hàm vlookup giữa 2 sheet

Sheet 1: Bảng chuyển đổi số thành chữ

Sheet 2: Bảng điểm của sinh viên

Yêu cầu: chuyển điểm ở cột Điểm HP từ điểm bằng số sang bằng chữ dựa vào bảng ở Sheet 1

 

Với ví dụ này ta sử dụng hàm Vlookup như sau:

Tại ô N8 nhập công thức: = VLOOKUP(M8;Sheet1!B2:C12;2;0)

Trong đó: 

• M8: Điểm HP bằng số
• Sheet1!B2:C12: Bảng tham chiếu ở Sheet 1
• 2: Thứ tự cột lấy dữ liệu
• 0 là kiểu dò tìm chính xác

Sau đó kéo hàm cho cả cột ta sẽ được kết quả như sau:

Cách sử dụng hàm vlookup giữa 2 sheet trong Excel

Ví dụ 4: Tiếp theo là ví dụ về cách sử dụng hàm vlookup kết hợp với 1 hàm khác

Yêu cầu: Tính cột đơn giá

Trong ví dụ này ta sẽ sử dụng hàm VLOOKUP kết hợp với hàm IF, LEFT, RIGHT để cho ra kết quả. Thực hiện như sau: 

Tại ô F2 ta nhập công thức: 

= VLOOKUP(LEFT(A2;3);$A$13:$E$17;IF(RIGHT(A2;2)= "SS";3;IF(RIGHT(A2;2)="TC";4;5)))

Trong đó:

• LEFT(A2;3): Là lấy 3 ký tự bên trái của ô A2 (Mã sản phẩm)
• $A$13:$E$17: Là bảng chứa dữ liệu 
• IF(RIGHT(A2;2)= "SS";3;IF(RIGHT(A2;2)="TC";4;5)): Nhóm hàm này để lấy thứ tự cột chứa đơn giá

4.2. Ví dụ hàm VLOOKUP trong kế toán

Hàm VLOOKUP được kế toán sử dụng nhiều khi cần tra cứu thông tin từ bảng danh mục sang bảng phát sinh. Thay vì nhập tay tên hàng, đơn giá, tên nhân viên, tên khách hàng hoặc số dư đầu kỳ, kế toán có thể dùng VLOOKUP để tự động lấy dữ liệu theo mã.

Dưới đây là các ví dụ thường gặp trong công việc kế toán thực tế.

Ví dụ 1: Tra cứu tên hàng theo mã hàng

Giả sử có bảng danh mục hàng hóa từ vùng A2:C10:

• Cột A: Mã hàng
• Cột B: Tên hàng
• Cột C: Đơn giá

Tại bảng bán hàng, ô E2 chứa mã hàng cần tra cứu. Để lấy tên hàng tương ứng, dùng công thức:

=VLOOKUP(E2;$A$2:$C$10;2;0)

Ý nghĩa công thức:

• E2 là mã hàng cần tìm.
• $A$2:$C$10 là bảng danh mục hàng hóa.
• 2 là cột chứa tên hàng trong vùng tra cứu.
• 0 là dò tìm chính xác.

Công thức này giúp kế toán tự động lấy tên hàng theo mã hàng, hạn chế tình trạng nhập sai tên hàng hoặc viết không thống nhất giữa các chứng từ.

Ví dụ 2: Tra cứu đơn giá theo mã hàng

Vẫn với bảng danh mục hàng hóa từ vùng A2:C10, nếu cần lấy đơn giá theo mã hàng tại ô E2, dùng công thức: =VLOOKUP(E2;$A$2:$C$10;3;0)

Công thức này tìm mã hàng tại ô E2 trong cột đầu tiên của bảng danh mục, sau đó trả về dữ liệu tại cột thứ 3, tức cột đơn giá.

Ví dụ này thường dùng khi lập bảng bán hàng, phiếu xuất kho, bảng kê hóa đơn hoặc bảng tính doanh thu theo từng mã sản phẩm.

Lưu ý: Nếu đơn giá thay đổi theo thời điểm, kế toán cần kiểm tra bảng giá áp dụng theo kỳ hoặc theo chính sách bán hàng. VLOOKUP chỉ lấy dữ liệu theo bảng tham chiếu đã chọn, nên bảng giá nguồn phải được cập nhật đúng trước khi dùng công thức.

Ví dụ 3: Tra cứu tên nhân viên theo mã nhân viên

Giả sử bảng danh sách nhân viên có:

• Cột A: Mã nhân viên
• Cột B: Họ và tên
• Cột C: Phòng ban
• Cột D: Chức vụ

Tại bảng lương, ô F2 chứa mã nhân viên. Để lấy họ và tên nhân viên, dùng công thức: 

=VLOOKUP(F2;$A$2:$D$100;2;0)

Nếu muốn lấy phòng ban của nhân viên, dùng công thức: =VLOOKUP(F2;$A$2:$D$100;3;0)

Nếu muốn lấy chức vụ, dùng công thức: =VLOOKUP(F2;$A$2:$D$100;4;0)

Cách làm này giúp kế toán tiền lương giảm thao tác nhập liệu thủ công, đặc biệt khi bảng lương có nhiều nhân sự hoặc cần lập nhiều bảng theo tháng.

Ví dụ 4: Tra cứu phụ cấp theo mã nhân viên

Giả sử bảng chính sách phụ cấp có:

• Cột A: Mã nhân viên
• Cột B: Phụ cấp trách nhiệm
• Cột C: Phụ cấp ăn trưa
• Cột D: Phụ cấp điện thoại

Tại bảng lương, ô E2 là mã nhân viên. Để lấy phụ cấp trách nhiệm, dùng công thức:

=VLOOKUP(E2;$A$2:$D$100;2;0)

Để lấy phụ cấp ăn trưa: =VLOOKUP(E2;$A$2:$D$100;3;0)

Để lấy phụ cấp điện thoại: =VLOOKUP(E2;$A$2:$D$100;4;0)

Khi áp dụng vào bảng lương, kế toán cần đảm bảo mã nhân viên ở bảng lương và bảng phụ cấp được nhập thống nhất. Nếu một mã nhân viên bị sai hoặc thiếu trong bảng phụ cấp, VLOOKUP sẽ trả về lỗi #N/A.

Ví dụ 5: Tra cứu thông tin khách hàng theo mã số thuế

Giả sử bảng danh mục khách hàng có:

• Cột A: Mã số thuế
• Cột B: Tên khách hàng
• Cột C: Địa chỉ
• Cột D: Email nhận hóa đơn

Tại bảng xuất hóa đơn, ô G2 chứa mã số thuế khách hàng. Để lấy tên khách hàng, dùng công thức:

=VLOOKUP(G2;$A$2:$D$200;2;0)

Để lấy địa chỉ khách hàng: =VLOOKUP(G2;$A$2:$D$200;3;0)

Ví dụ này rất hữu ích khi kế toán cần lập bảng kê hóa đơn, kiểm tra thông tin khách hàng hoặc đồng bộ dữ liệu từ danh mục khách hàng sang bảng phát sinh.

Với dữ liệu khách hàng, nên dùng mã số thuế hoặc mã khách hàng làm khóa tra cứu thay vì tên doanh nghiệp. Tên doanh nghiệp có thể được nhập khác nhau ở nhiều dòng, trong khi mã số thuế thường là thông tin ổn định hơn.

Ví dụ 6: Tra cứu nhà cung cấp theo mã đối tượng

Giả sử bảng danh mục nhà cung cấp có:

• Cột A: Mã nhà cung cấp
• Cột B: Tên nhà cung cấp
• Cột C: Người liên hệ
• Cột D: Điều khoản thanh toán

Tại bảng công nợ phải trả, ô E2 là mã nhà cung cấp. Để lấy tên nhà cung cấp, dùng công thức:

=VLOOKUP(E2;$A$2:$D$150;2;0)

Để lấy điều khoản thanh toán, dùng công thức: =VLOOKUP(E2;$A$2:$D$150;4;0)

Công thức này giúp kế toán dễ kiểm tra công nợ theo đối tượng, theo dõi điều khoản thanh toán và lập kế hoạch chi tiền cho nhà cung cấp.

Ví dụ 7: Lấy số dư đầu kỳ theo mã tài khoản

Giả sử bảng số dư đầu kỳ có:

• Cột A: Tài khoản kế toán
• Cột B: Tên tài khoản
• Cột C: Dư Nợ đầu kỳ
• Cột D: Dư Có đầu kỳ

Tại bảng tổng hợp, ô F2 là tài khoản cần tra cứu. Để lấy số dư Nợ đầu kỳ, dùng công thức:

=VLOOKUP(F2;$A$2:$D$200;3;0)

Để lấy số dư Có đầu kỳ: =VLOOKUP(F2;$A$2:$D$200;4;0)

Ví dụ này thường dùng khi kế toán muốn lấy dữ liệu từ bảng số dư sang bảng tổng hợp, bảng kiểm tra số liệu hoặc file hỗ trợ lập báo cáo.

Lưu ý: Với tài khoản kế toán, cần thống nhất định dạng tài khoản là text hoặc số. Nếu một bảng lưu tài khoản 1121 dưới dạng số, bảng khác lưu dưới dạng text, công thức có thể không khớp và trả về lỗi.

Ví dụ 8: Dùng VLOOKUP giữa 2 sheet

Trong thực tế, bảng danh mục và bảng phát sinh thường nằm ở hai sheet khác nhau. Ví dụ:

• Sheet DanhMucHang: chứa danh mục hàng hóa từ vùng A2:D100
• Sheet BanHang: chứa bảng bán hàng, ô B2 là mã hàng cần tra cứu

Tại sheet BanHang, để lấy tên hàng từ sheet DanhMucHang, dùng công thức: 

=VLOOKUP(B2;DanhMucHang!$A$2:$D$100;2;0)

Để lấy đơn giá: =VLOOKUP(B2;DanhMucHang!$A$2:$D$100;4;0)

Cách viết này giúp kết nối dữ liệu giữa các sheet trong cùng một file Excel. Khi dùng công thức giữa nhiều sheet, kế toán nên đặt tên sheet ngắn, rõ nghĩa và tránh đổi tên sheet sau khi đã lập công thức để hạn chế lỗi tham chiếu.

Ví dụ 9: VLOOKUP nhiều điều kiện bằng cột phụ

Bản chất VLOOKUP chỉ tra cứu theo một giá trị. Nếu muốn tra cứu theo nhiều điều kiện, có thể tạo cột phụ bằng cách ghép các điều kiện lại thành một khóa duy nhất.

Ví dụ cần tra cứu đơn giá theo cả mã hàng và kho hàng. Bảng danh mục có:

• Cột A: Mã hàng
• Cột B: Kho hàng
• Cột C: Đơn giá

Có thể tạo cột phụ tại cột D bằng công thức: =A2&"-"&B2

Cột D sẽ tạo khóa dạng MH01-KHOA, MH01-KHOB, MH02-KHOA.

Tại bảng cần tra cứu, nếu ô F2 là mã hàng và ô G2 là kho hàng, công thức VLOOKUP có thể viết:

=VLOOKUP(F2&"-"&G2;$D$2:$E$100;2;0)

Trong đó, vùng $D$2:$E$100 cần được thiết kế sao cho cột đầu tiên là cột khóa phụ, cột thứ hai là cột đơn giá cần trả về.

Cách này giúp xử lý một số tình huống tra cứu nhiều điều kiện, nhưng với bảng dữ liệu phức tạp hơn, kế toán nên cân nhắc dùng XLOOKUP, INDEX kết hợp MATCH hoặc các công cụ xử lý dữ liệu nâng cao.

Ví dụ 10: VLOOKUP kết hợp IFERROR để xử lý lỗi

Khi mã cần tìm không có trong bảng tra cứu, VLOOKUP thường trả về lỗi #N/A. Để bảng tính dễ đọc hơn, có thể kết hợp VLOOKUP với IFERROR.

Ví dụ: =IFERROR(VLOOKUP(E2;$A$2:$D$100;2;0);"Không tìm thấy mã")

Công thức này có nghĩa là:

• Nếu VLOOKUP tìm thấy dữ liệu, Excel trả về kết quả tra cứu.
• Nếu không tìm thấy, Excel hiển thị “Không tìm thấy mã” thay vì lỗi #N/A.

Trong kế toán, IFERROR giúp bảng tính gọn hơn, nhưng không nên dùng để che lỗi một cách máy móc. Nếu kết quả trả về “Không tìm thấy mã”, kế toán vẫn cần kiểm tra lại bảng danh mục, mã đối tượng hoặc dữ liệu nguồn để xử lý đúng nguyên nhân.

Tham khảo video hướng dẫn chi tiết cách sử dụng hàm VLOOKUP - ví dụ trong kế toán dưới đây:

5. Công dụng của hàm VLOOKUP trong Excel kế toán

• Lập các thông tin trên Phiếu thu, phiếu chi
• Tìm đơn giá Xuất kho từ bên Bảng Nhập Xuất Tồn về BNL, về Phiếu Xuất kho…
• Tìm Mã hàng hoá, tên hàng hoá từ DMTK về Bảng Nhập Xuất Tồn.
• Tìm số dư của đầu tháng N căn cứ vào cột số dư của tháng N-1.
• Tìm số “Khấu hao (Phân bổ) luỹ kế từ kỳ trước” của Bảng khấu hao (bảng phân phối chi phí), căn cứ vào Giá trị khấu hao (phân bổ) luỹ kế của thang N-1.
• Và các bảng khác liên quan….

Hàm VLOOKUP trong Excel là công cụ vô cùng hữu ích giúp bạn tra cứu dữ liệu nhanh chóng, chính xác, thay thế cho việc dò thủ công tốn nhiều thời gian. Việc nắm vững cú pháp hàm VLOOKUP, áp dụng đúng mẫu hàm VLOOKUP trong Excel và biết cách xử lý các lỗi thường gặp sẽ giúp bạn nâng cao hiệu quả làm việc, đặc biệt trong các nghiệp vụ kế toán, quản lý kho, lương và công nợ.

Với người làm kế toán, VLOOKUP không chỉ là kỹ năng tin học văn phòng, mà còn là “trợ thủ đắc lực” trong việc lập báo cáo, kiểm tra dữ liệu và hạch toán chứng từ. Nếu biết kết hợp với các hàm nâng cao như IF, INDEX, MATCH hoặc XLOOKUP, bạn sẽ có thể xử lý bảng tính phức tạp một cách linh hoạt và chuyên nghiệp hơn.

6. Cách sử dụng hàm VLOOKUP nâng cao

Ngoài cách dùng cơ bản, hàm VLOOKUP trong Excel có thể được kết hợp với các thủ thuật để giải quyết những tình huống phức tạp hơn trong công việc kế toán và quản lý dữ liệu.

6.1. VLOOKUP nhiều điều kiện

Mặc định, hàm VLOOKUP chỉ có thể tra cứu theo một điều kiện duy nhất. Tuy nhiên, trong thực tế, đôi khi bạn cần tìm kiếm dữ liệu dựa trên nhiều tiêu chí kết hợp (ví dụ: cùng một mã hàng nhưng có nhiều đơn giá khác nhau tùy theo đơn vị tính: cái, hộp, thùng,…).

Cách giải quyết: tạo một cột phụ ghép nhiều điều kiện lại thành một "khóa tra cứu duy nhất".

Ví dụ minh họa: Tra cứu theo nhiều tiêu chí (ví dụ: vừa theo mã nhân viên, vừa theo tháng lương)

Cách thực hiện:

Bước 1 – Tạo cột phụ ghép dữ liệu: 

Tại ô E2 nhập công thức: =A2& "-" B2

Kéo xuống hết các dòng có dữ liệu.

Tại F2 nhập: =D2

Bước 2: Tạo khu vực tra cứu

Điền Mã NV vào A10 (ví dụ NV01) và Tháng vào B10 (ví dụ 1).

Ô C10 tạo khóa tra cứu: =A10&"-"&B10

Bước 3 – Dùng VLOOKUP để trả về Lương thực nhận:

Tại ô D10 dùng công thức: =VLOOKUP(C10;E1:F7;2;0)

Lấy được lương tháng 1 của nhân viên NV01 là: 9.500.000

Tải file Excel thực hành Hàm Vlookup nhiều điều kiện: TẠI ĐÂY

6.2. VLOOKUP dữ liệu từ nhiều sheet

Trong nhiều trường hợp, dữ liệu không chỉ nằm trên một bảng, mà được phân tách thành nhiều sheet khác nhau (ví dụ: sheet theo từng năm, từng chi nhánh, hay từng kho hàng). Khi đó, bạn hoàn toàn có thể dùng hàm VLOOKUP để tra cứu dữ liệu từ các sheet khác.

Ví dụ: Bạn có bảng dữ liệu hàng hóa trong Sheet2 (cột A là Mã hàng, cột B là Đơn vị tính, cột C là Giá bán).

Bạn có thể tra cứu dữ liệu từ nhiều sheet khác nhau.

Nếu muốn lấy Giá bán (VNĐ) của mã hàng là "A01" đơn vị tính là"Cái", công thức ở Ô D2 sẽ là: =VLOOKUP(C2;BangGia!D1:E5; 2; 0)

Tải file Excel thực hành Hàm Vlookup giữa 2 sheet: TẠI ĐÂY

Mẹo: Kết hợp với INDIRECT để tham chiếu động đến tên sheet theo ô nhập vào.

6.3. Kết hợp VLOOKUP với hàm IF

Trong một số trường hợp, bạn có nhiều bảng dữ liệu (ví dụ: nhiều kho hàng khác nhau), nhưng muốn công thức chỉ tra cứu trong kho mà bạn chọn. Khi đó, bạn có thể kết hợp hàm VLOOKUP với IF để xử lý linh hoạt.

Ví dụ minh họa: Giả sử bạn có 2 sheet dữ liệu

• Sheet Kho1: Chứa danh sách hàng hóa ở kho 1.
• Sheet Kho2: Chứa danh sách hàng hóa ở kho 2.

Ở sheet TraCuu, bạn nhập:

• Ô A1: tên kho muốn tra cứu (Kho1 hoặc Kho2).
• Ô B1: mã hàng cần tra cứu (ví dụ: A02).

Công thức tại ô C1 (kết quả Tên hàng):

=IF(A1="Kho1"; VLOOKUP(B1; Kho1!A2:C100; 2; 0); VLOOKUP(B1; Kho2!A2:C100; 2; 0))

• Nếu A1 = Kho1 → Excel tìm trong bảng Kho1.
• Nếu A1 = Kho2 → Excel tìm trong bảng **Kho2`.

Tải file Excel thực hành Hàm Vlookup kết hợp hàm IF: TẠI ĐÂY

Ứng dụng thực tế

• Kế toán muốn tra cứu giá hàng hóa theo kho (Kho HN, Kho HCM).
• Quản lý muốn so sánh giá bán giữa các chi nhánh.
• Giảm thời gian viết nhiều công thức cho từng bảng.

6.4. Sử dụng XLOOKUP thay thế VLOOKUP (Excel 365/2019)

Trong phiên bản mới, Microsoft khuyến khích dùng XLOOKUP vì linh hoạt hơn:

• Không bị giới hạn tìm kiếm ở cột đầu tiên.
• Có thể tìm từ trái sang phải.
• Trả về nhiều giá trị cùng lúc.

Ví dụ XLOOKUP: =XLOOKUP("A03", A2:A4, C2:C4)

Tìm mã hàng A03 trong cột A, trả về đơn giá ở cột C.

Gợi ý cho kế toán:

• Dùng hàm VLOOKUP nhiều điều kiện khi cần tra cứu dữ liệu lương theo tháng/năm.
• Dùng hàm VLOOKUP nhiều sheet khi dữ liệu được chia theo năm hoặc theo chi nhánh.
• Nếu dùng Excel 365, chuyển sang XLOOKUP để tiết kiệm thời gian và giảm lỗi.

7. Lưu ý khi sử dụng hàm Vlookup

#1 - Lưu ý về dấu ngăn cách trong công thức

Trong Excel, các tham số của hàm VLOOKUP có thể được ngăn cách bằng dấu phẩy (,) hoặc dấu chấm phẩy (;), tùy thuộc vào thiết lập ngôn ngữ và định dạng hệ thống.

• Thông thường: Excel tiếng Anh → dùng dấu phẩy ,

• Excel tiếng Việt hoặc một số máy cài đặt chuẩn dấu thập phân bằng dấu phẩy → dùng dấu chấm phẩy ;

• Nếu công thức báo lỗi khi bạn copy từ nguồn khác, hãy thử đổi dấu , ↔ ; để phù hợp với máy của bạn.

#2 - Trong Excel, VLOOKUP luôn tìm giá trị trong cột đầu tiên của vùng dữ liệu (table_array). Từ cột này, hàm có thể trả về dữ liệu ở bất kỳ cột nào bên phải nhờ tham số col_index_num.

Nếu bạn muốn tra cứu ở một cột nhưng cần lấy dữ liệu ở cột nằm bên trái, VLOOKUP sẽ không thực hiện trực tiếp được. Khi đó, bạn có thể:

• Dùng hàm CHOOSE để tạo lại vùng dữ liệu theo thứ tự mong muốn,
• Hoặc sử dụng các hàm linh hoạt hơn như INDEX + MATCH hoặc XLOOKUP (Excel 365/2019).

Ví dụ: Giả sử bạn có bảng dữ liệu:

• Trường hợp thông thường (tra từ trái sang phải): =VLOOKUP("A02"; A2:C4; 3; 0) - Kết quả: 12.000 (Đơn giá của A02).
• Trường hợp muốn tra từ phải sang trái (tìm theo Tên hàng, trả về Mã hàng): =VLOOKUP("Máy tính Casio"; CHOOSE({1;2}; B2:B4; A2:A4); 2; 0) - Kết quả: A03

#3 - Sử dụng F4 để cố định dòng, cột:

• F4 (1 lần): để có giá trị tuyệt đối. Tuyệt đối được hiểu là cố định cột và cố định dòng  ⇒  $cột$dòng

Ví dụ: $B$9 ⇒ cố định cột B và cố định dòng 9

• F4 (2 lần): để có giá trị tương đối cột và tuyệt đối dòng – Được hiểu là cố định dòng , không cố định cột ⇒ cột$dòng

Ví dụ: B$9 ⇒ cố định dòng 9, không cố định cột B

• F4 (3 lần): để có giá trị tương đối dòng và tuyệt đối cột- Được hiểu là cố định cột, không cố định dòng ⇒ $cộtdòng

Ví dụ: $B9 ⇒ cố định cột B, không cố định dòng 9

8. Các lỗi thường gặp khi dùng VLOOKUP và cách sửa

Hàm VLOOKUP khá dễ dùng ở mức cơ bản, nhưng trong thực tế kế toán vẫn thường gặp nhiều lỗi do sai vùng tra cứu, sai kiểu dữ liệu, thiếu cố định vùng hoặc chọn chưa đúng kiểu dò tìm. Có trường hợp Excel báo lỗi rõ ràng như #N/A, #REF!, #VALUE!, nhưng cũng có trường hợp công thức vẫn trả kết quả mà kết quả đó lại không đúng.

Dưới đây là các lỗi phổ biến nhất khi dùng VLOOKUP và cách xử lý.

Lỗi 1: VLOOKUP bị lỗi #N/A

Lỗi #N/A xuất hiện khi VLOOKUP không tìm thấy giá trị cần tra cứu trong cột đầu tiên của vùng dữ liệu.

Ví dụ: =VLOOKUP(E2;$A$2:$D$100;2;0)

Nếu giá trị tại ô E2 không tồn tại trong cột A của vùng $A$2:$D$100, Excel sẽ trả về lỗi #N/A.

Nguyên nhân thường gặp:

• Mã cần tìm chưa có trong bảng danh mục.
• Mã ở bảng phát sinh và bảng danh mục nhập không giống nhau.
• Một bên là dữ liệu dạng số, một bên là dữ liệu dạng text.
• Có khoảng trắng thừa trước hoặc sau mã.
• Gõ sai ký tự, sai dấu, sai định dạng mã.

Cách sửa:

• Kiểm tra lại mã cần tìm trong bảng danh mục.
• Dùng hàm TRIM để loại bỏ khoảng trắng thừa.
• Chuẩn hóa định dạng mã về cùng kiểu text hoặc cùng kiểu số.
• Dùng mã đối tượng thống nhất ngay từ đầu.
• Có thể kết hợp IFERROR để hiển thị thông báo dễ hiểu hơn.

Ví dụ: =IFERROR(VLOOKUP(E2;$A$2:$D$100;2;0);"Không tìm thấy mã")

Tuy nhiên, kế toán không nên chỉ dùng IFERROR để che lỗi. Nếu công thức báo “Không tìm thấy mã”, cần kiểm tra lại dữ liệu nguồn để xác định nguyên nhân thật sự.

Lỗi 2: VLOOKUP bị lỗi #REF!

Lỗi #REF! thường xuất hiện khi số thứ tự cột trả về lớn hơn số cột trong vùng tra cứu.

Ví dụ sai: =VLOOKUP(E2;$A$2:$C$100;4;0)

Vùng $A$2:$C$100 chỉ có 3 cột, nhưng công thức lại yêu cầu trả về cột thứ 4. Vì vậy Excel không thể xác định cột cần trả kết quả và báo lỗi #REF!.

Cách sửa:

• Kiểm tra lại vùng tra cứu có bao nhiêu cột.
• Kiểm tra lại col_index_num.
• Mở rộng vùng tra cứu nếu cột cần trả về nằm ngoài vùng đang chọn.

Ví dụ đúng: =VLOOKUP(E2;$A$2:$D$100;4;0)

Công thức này hợp lệ vì vùng $A$2:$D$100 có 4 cột và col_index_num là 4.

Lỗi 3: VLOOKUP bị lỗi #VALUE!

Lỗi #VALUE! có thể xảy ra khi một đối số trong công thức không hợp lệ, đặc biệt là col_index_num.

Ví dụ, nếu số thứ tự cột trả về nhỏ hơn 1 hoặc không phải giá trị hợp lệ, công thức có thể báo lỗi.

Ví dụ sai: =VLOOKUP(E2;$A$2:$D$100;0;0)

Trong VLOOKUP, cột đầu tiên của vùng tra cứu được tính là cột 1. Vì vậy col_index_num không thể là 0.

Cách sửa:

• Đảm bảo col_index_num là số nguyên từ 1 trở lên.
• Kiểm tra lại dấu phân cách đối số là ; hay ,.
• Kiểm tra công thức có thiếu hoặc thừa dấu ngoặc không.

Lỗi 4: VLOOKUP bị lỗi #NAME?

Lỗi #NAME? thường xuất hiện khi Excel không nhận diện được tên hàm, tên vùng hoặc nội dung trong công thức.

Nguyên nhân có thể là:

• Gõ sai tên hàm, ví dụ VLOKUP thay vì VLOOKUP.
• Thiếu dấu nháy kép với điều kiện dạng chữ.
• Tên vùng dữ liệu không tồn tại.
• Công thức có ký tự không hợp lệ.

Ví dụ sai: =VLOKUP(E2;$A$2:$D$100;2;0)

Cách sửa:

• Kiểm tra lại chính tả hàm VLOOKUP.
• Kiểm tra tên vùng nếu đang dùng Named Range.
• Đặt chuỗi văn bản trong dấu nháy kép khi cần.
• Kiểm tra dấu ngoặc mở và dấu ngoặc đóng.

Lỗi 5: VLOOKUP trả về sai kết quả

Đây là lỗi nguy hiểm vì công thức không báo lỗi nhưng kết quả trả về không đúng. Với kế toán, lỗi này có thể làm sai đơn giá, sai tên đối tượng, sai công nợ hoặc sai dữ liệu báo cáo.

Nguyên nhân thường gặp là dùng dò tìm gần đúng trong khi cần tìm chính xác.

Ví dụ: =VLOOKUP(E2;$A$2:$D$100;3;1)

Hoặc: =VLOOKUP(E2;$A$2:$D$100;3)

Khi bỏ qua đối số cuối, Excel có thể hiểu là dò tìm gần đúng. Nếu bảng dữ liệu chưa được sắp xếp đúng hoặc mã cần tìm không khớp hoàn toàn, kết quả có thể sai.

Với dữ liệu kế toán như mã hàng, mã nhân viên, mã khách hàng, mã số thuế, mã nhà cung cấp, mã tài khoản, nên dùng: =VLOOKUP(E2;$A$2:$D$100;3;0)

Hoặc: =VLOOKUP(E2;$A$2:$D$100;3;FALSE)

Cách này yêu cầu Excel tìm chính xác giá trị cần tra cứu.

Lỗi 6: Không cố định vùng tra cứu khi kéo công thức

Khi kéo công thức VLOOKUP xuống nhiều dòng, nếu không cố định vùng tra cứu, bảng tham chiếu có thể bị trượt theo từng dòng và làm kết quả sai.

Ví dụ chưa cố định: =VLOOKUP(E2;A2:D100;2;0)

Khi kéo xuống dòng tiếp theo, vùng tra cứu có thể thay đổi thành A3:D101, khiến Excel bỏ sót dòng đầu tiên của bảng danh mục.

Công thức nên viết: =VLOOKUP(E2;$A$2:$D$100;2;0)

Dấu $ giúp cố định vùng $A$2:$D$100 khi sao chép công thức sang các dòng khác.

Lỗi 7: Mã cần tìm và mã trong bảng tra cứu khác định dạng

Một lỗi rất thường gặp trong file kế toán là cùng một mã nhưng định dạng khác nhau. Ví dụ, ô cần tìm là số 1121, nhưng bảng tra cứu lại lưu "1121" dưới dạng text. Nhìn bằng mắt thường giống nhau, nhưng Excel có thể hiểu là hai kiểu dữ liệu khác nhau.

Tình huống này thường gặp với:

• Mã tài khoản kế toán.
• Mã hàng hóa.
• Mã nhân viên.
• Mã khách hàng.
• Mã số thuế.
• Số chứng từ.

Cách xử lý:

• Chuẩn hóa cả hai cột về cùng kiểu dữ liệu.
• Nếu cần giữ số 0 ở đầu mã, nên định dạng mã ở dạng text.
• Kiểm tra dữ liệu copy từ phần mềm kế toán, file xuất Excel hoặc hệ thống bán hàng.
• Dùng TRIM để loại khoảng trắng thừa.

Lỗi 8: Bảng danh mục có mã trùng

VLOOKUP chỉ trả về kết quả khớp đầu tiên mà hàm tìm thấy. Nếu bảng danh mục có nhiều dòng trùng mã nhưng thông tin khác nhau, công thức có thể trả về kết quả không đúng kỳ vọng.

Ví dụ:

Nếu dùng VLOOKUP để tra mã HH01, Excel sẽ trả về đơn giá ở dòng đầu tiên mà hàm tìm thấy. Trong ví dụ trên, kết quả có thể là 100.000, dù người dùng đang muốn lấy đơn giá mới hơn.

Cách xử lý:

• Kiểm tra và loại bỏ mã trùng trong bảng danh mục.
• Nếu đơn giá thay đổi theo thời gian, cần bổ sung thêm điều kiện ngày hoặc kỳ áp dụng.
• Tạo khóa phụ gồm mã hàng + kỳ áp dụng nếu cần tra cứu nhiều điều kiện.
• Dùng XLOOKUP, FILTER hoặc Power Query trong các tình huống phức tạp hơn.

Lỗi 9: VLOOKUP không tra cứu được dữ liệu bên trái

VLOOKUP chỉ tìm giá trị ở cột đầu tiên của vùng tra cứu và trả về dữ liệu ở các cột bên phải. Nếu cần tìm mã hàng từ tên hàng, hoặc lấy dữ liệu nằm bên trái cột tra cứu, VLOOKUP không phải lựa chọn phù hợp.

Ví dụ, bảng dữ liệu có:

• Cột A: Tên hàng
• Cột B: Mã hàng

Nếu muốn tìm mã hàng dựa trên tên hàng, VLOOKUP có thể dùng được vì mã hàng nằm bên phải tên hàng. Nhưng nếu bảng có:

• Cột A: Mã hàng
• Cột B: Tên hàng

và muốn tìm mã hàng theo tên hàng, VLOOKUP sẽ khó xử lý nếu không sắp xếp lại bảng.

Cách xử lý:

• Sắp xếp lại bảng để cột cần tra cứu nằm ngoài cùng bên trái.
• Dùng XLOOKUP nếu phiên bản Excel hỗ trợ.
• Dùng INDEX kết hợp MATCH để tra cứu linh hoạt hơn.

Lỗi 10: Công thức sai sau khi thêm hoặc xóa cột

VLOOKUP dùng số thứ tự cột để trả kết quả. Khi thêm hoặc xóa cột trong vùng tra cứu, số thứ tự cột có thể không còn đúng như ban đầu.

Ví dụ ban đầu: =VLOOKUP(E2;$A$2:$D$100;4;0)

Cột thứ 4 đang là đơn giá. Nếu người dùng chèn thêm một cột mới trước cột đơn giá, vị trí cột đơn giá thay đổi. Công thức có thể không còn trả đúng dữ liệu cần lấy.

Cách xử lý:

• Kiểm tra lại col_index_num sau khi thêm hoặc xóa cột.
• Hạn chế thay đổi cấu trúc bảng danh mục đã dùng cho nhiều công thức.
• Dùng XLOOKUP hoặc INDEX MATCH trong các bảng dữ liệu thường xuyên thay đổi cột.

9. Cách kiểm tra nhanh công thức VLOOKUP trước khi dùng cho báo cáo

Trước khi dùng kết quả VLOOKUP cho bảng lương, công nợ, hàng tồn kho hoặc báo cáo quản trị, kế toán nên kiểm tra nhanh các điểm sau:

• Giá trị cần tìm có tồn tại trong cột đầu tiên của vùng tra cứu không.
• Vùng tra cứu đã được cố định bằng dấu $ chưa.
• Cột đầu tiên của vùng tra cứu có đúng là cột chứa mã cần tìm không.
• Số thứ tự cột trả về đã đúng chưa.
• Kiểu dò tìm đã dùng 0/FALSE khi cần khớp chính xác chưa.
• Mã cần tìm và mã trong bảng tra cứu có cùng định dạng không.
• Bảng danh mục có bị trùng mã không.
• Có dòng trống, dòng tổng hoặc ô gộp trong bảng tra cứu không.
• Công thức có bị ảnh hưởng sau khi thêm hoặc xóa cột không.
• Kết quả đã được kiểm tra chéo với một vài dòng mẫu chưa.

Thói quen kiểm tra này giúp hạn chế rủi ro sai số liệu, nhất là khi file Excel được dùng để lập bảng lương, đối chiếu công nợ, kiểm tra đơn giá hoặc tổng hợp báo cáo kế toán.

Xem thêm:

• 10+ Hàm Excel Thường Dùng Trong Kế Toán
• Cách sử dụng hàm Sumif trong Excel
• Cách sử dụng hàm Subtotal trong Excel
• Cách Dùng Hàm COUNTIF, COUNTIFS Trong Excel
• Cách sử dụng hàm IF trong Excel

Để học thêm các kỹ năng Excel kế toán ứng dụng thực tế, cũng như nắm vững các công cụ hỗ trợ phân tích số liệu, bạn có thể tham khảo các khóa học kế toán thực hành tại Kế toán Lê Ánh. Các giảng viên là chuyên gia nhiều năm kinh nghiệm sẽ hướng dẫn bạn cách sử dụng Excel không chỉ để “làm nhanh” mà còn để “làm chuẩn” theo đúng yêu cầu công việc.

Tags: Hàm vlookup nâng cao, hàm hlookup trong excel, hàm vlookup có điều kiện, bai tap hàm vlookup trong excel, cách dùng hàm vlookup giữa 2 sheet, hàm tìm kiếm tên trong excel, hàm vlookup và hlookup, cách dùng hàm vlookup giữa 2 file 

Kế Toán Lê Ánh - Nơi đào tạo kế toán thực hành uy tín nhất hiện nay, đã tổ chức thành công rất nhiều khóa học nguyên lý kế toán, khóa học kế toán tổng hợp online/ offline, khóa học kế toán thuế cho người mới bắt đầu, khóa học kế toán cao cấp, khóa học kế toán xây dựng, sản xuất, khóa học kế toán quản trị, khóa học kế toán thuế chuyên sâu, khóa học phân tích tài chính... và hỗ trợ kết nối tuyển dụng cho hàng nghìn học viên.

Nếu như bạn muốn tham gia các khóa học kế toán của trung tâm Lê Ánh thì có thể liên hệ hotline tư vấn: 0904.84.8855/ Mrs Lê Ánh 

Ngoài các khóa học kế toán thì trung tâm Lê Ánh còn cung cấp các khóa học xuất nhập khẩu online - offline, khóa học hành chính nhân sự online - offline chất lượng tốt nhất hiện nay.

Thực hiện bởi: KẾ TOÁN LÊ ÁNH - TRUNG TÂM ĐÀO TẠO KẾ TOÁN SỐ 1 VIỆT NAM